Zig allocator demo, using extram

apps/zigalloc/src/console.zig

@@ -0,0 +1,49 @@
+const std = @import("std");
+extern fn console_write(data: [*]const u8, len: usize) void;
+var wbuf:[4096]u8 = undefined;
+var cw = ConsoleWriter.init(&wbuf);
+const uvm = @import("uvm.zig");
+
+pub const WriteError = error{ Unsupported, NotConnected };
+
+pub const ConsoleWriter = struct {
+    interface: std.Io.Writer,
+    err: ?WriteError = null,
+
+    fn drain(w: *std.Io.Writer, data: []const []const u8, splat: usize) std.Io.Writer.Error!usize {
+        var ret: usize = 0;
+
+        const b = w.buffered();
+        uvm.print(b);
+        _ = w.consume(b.len);
+
+        for (data) |d| {
+            uvm.print(d);
+            ret += d.len;
+        }
+
+        const pattern = data[data.len - 1];
+        for (0..splat) |_| {
+            uvm.print(pattern);
+            ret += pattern.len;
+        }
+
+        return ret;
+    }
+
+    pub fn init(buf: []u8) ConsoleWriter {
+        return ConsoleWriter{
+            .interface = .{
+                .buffer = buf,
+                .vtable = &.{
+                    .drain = drain,
+                },
+            },
+        };
+    }
+};
+
+pub fn getWriter() *std.Io.Writer {
+    return &cw.interface;
+}
+

apps/zigalloc/src/main.zig

@@ -0,0 +1,18 @@
+const uvm = @import("uvm.zig");
+const console = @import("console.zig").getWriter();
+
+fn submain() !void {
+    try console.print("Hello world\n", .{});
+    try console.flush();
+
+    const foo = try uvm.allocator().dupe(u8, "copy me");
+    try console.print("dupe={s}\n", .{foo});
+    try console.flush();
+
+}
+
+export fn main() void {
+    _ = submain() catch {
+        uvm.println("Caught err");
+    };
+}

apps/zigalloc/src/uvm.zig

@@ -0,0 +1,65 @@
+const uvm32 = @cImport({
+    @cDefine("USE_MAIN", "1");
+    @cInclude("uvm32_target.h");
+});
+const buildopts = @import("buildopts");
+const std = @import("std");
+
+const extram:[*]u8 = @ptrFromInt(uvm32.UVM32_EXTRAM_BASE);
+const extram_len = buildopts.heapsize;
+
+var fba:std.heap.FixedBufferAllocator = .init(extram[0..extram_len]);
+
+pub fn allocator() std.mem.Allocator {
+    return fba.allocator();
+}
+
+pub inline fn syscall(id: u32, param1: u32, param2: u32) u32 {
+    var val: u32 = undefined;
+    asm volatile ("ecall"
+        : [val] "={a1}" (val),
+        : [param1] "{a0}" (param1), [param2] "{a1}" (param2),
+          [id] "{a7}" (id),
+        : .{ .memory = true });
+    return val;
+}
+
+pub inline fn getc() ?u8 {
+    const key = syscall(uvm32.UVM32_SYSCALL_GETC, 0, 0);
+    if (key == 0xFFFFFFFF) {
+        return null;
+    } else {
+        return @truncate(key);
+    }
+}
+
+pub inline fn millis() u32 {
+    return syscall(uvm32.UVM32_SYSCALL_MILLIS, 0, 0);
+}
+
+// dupeZ would be better, but want to avoid using an allocator
+// this is of course, unsafe...
+var termination_buf:[128]u8 = undefined;
+
+pub inline fn print(m: []const u8) void {
+    @memcpy(termination_buf[0..m.len], m);
+    termination_buf[m.len] = 0;
+    const s = termination_buf[0..m.len :0];
+    _ = syscall(uvm32.UVM32_SYSCALL_PRINT, @intFromPtr(s.ptr), 0);
+}
+
+pub inline fn println(m: []const u8) void {
+    @memcpy(termination_buf[0..m.len], m);
+    termination_buf[m.len] = 0;
+    const s = termination_buf[0..m.len :0];
+    _ = syscall(uvm32.UVM32_SYSCALL_PRINTLN, @intFromPtr(s.ptr), 0);
+}
+
+pub inline fn yield() void {
+    _ = syscall(uvm32.UVM32_SYSCALL_YIELD, 0, 0);
+}
+
+pub inline fn putc(c:u8) void {
+    _ = syscall(uvm32.UVM32_SYSCALL_PUTC, c, 0);
+}
+